我，本作品著作权人，特此采用以下许可协议发表本作品：

本文件采用知识共享署名-相同方式共享 3.0 未本地化版本许可协议授权。

您可以自由地：

• 共享 – 复制、发行并传播本作品
• 修改 – 改编作品

惟须遵守下列条件：

• 署名 – 您必须对作品进行署名，提供授权条款的链接，并说明是否对原始内容进行了更改。您可以用任何合理的方式来署名，但不得以任何方式表明许可人认可您或您的使用。
• 相同方式共享 – 如果您再混合、转换或者基于本作品进行创作，您必须以与原先许可协议相同或相兼容的许可协议分发您贡献的作品。

https://creativecommons.org/licenses/by-sa/3.0CC BY-SA 3.0 Creative Commons Attribution-Share Alike 3.0 truetrue

set term svg size 800,600 enhanced font 'Times,12'
set output 'Natural_Logarithm_All.svg'

set multiplot

set xlabel "x"
set ylabel "y"
set zlabel "z"
set xrange [-2.5:2.5]
set yrange [-2.0:2.0]
set zrange [-3:4]
set box
unset colorbox
#set view 65,45

set cntrparam levels auto 20
set contour base
set isosamples 60,60
set samples 60,60
set pm3d
set hidd
unset key
set ticslevel 0
i = {0.0,1.0}

# Draw the surface of Re(ln(x+i*y))
set palette defined (-1 "blue", 1 "pink")
splot real(log(x+i*y))

# Draw the surface of |Im(ln(x+i*y))|
set palette defined (-1 "yellow", 1 "orange")
splot abs(imag(log(x+i*y)))

# Draw the surface of |ln(x+i*y)|
set palette defined (-1 "red", 1 "orange")
splot abs(log(x+i*y))

# Draw the lines
unset cntrparam
unset contour
set isosamples 20,20
set samples 20,20
unset pm3d
unset hidd

# Draw the lines of Re(ln(x+i*y))
splot real(log(x+i*y)) lt 2 lc rgb "black" lw 0.1

# Draw the lines of |Im(ln(x+i*y))|
splot abs(imag(log(x+i*y))) lt 2 lc rgb "black" lw 0.1

# Draw the lines of |ln(x+i*y)|
splot abs(log(x+i*y)) lt 2 lc rgb "black" lw 0.1

unset multiplot
set term x11
set output